안녕하세요?
다수의 채굴기를 일괄적으로 세팅하다보니 아이피설정이나 컴퓨터 이름 바꾸는 것 조차 번거롭게 느껴져서 간편하게 아이피를 설정하고 컴퓨터 이름을 아이피 기준으로 자동 부여되도록 배치파일을 만들어 봤습니다.
[배치파일 설정]
배치파일을 열면 상단에 세팅 값을 설정하는 곳이 있습니다.
<IP 관련>
1. set NIC=이더넷
2. set GATEWAY=192.168.0.1
3. set SUBNET=255.255.255.0
4. set DNS1=168.126.63.1
5. set DNS2=168.126.63.2
1. 은 네트워크 어뎁터의 이름을 적는 곳입니다.
2는 사용하시는 공유기의 ip(게이트웨이)를
4,5는 이용하시는 인터넷 회사의 DNS 서버 주소를 설정하시면 됩니다. 본 배치파일에는 KT의 정보가 입력되어 있습니다.
<컴퓨터 이름 관련>
배치파일 중간에 아래와 같은 명령어가 있습니다.
if %IPend% LSS 10 set COMName=PC00
if %IPend% GTR 9 set COMName=PC0
if %IPend% GTR 99 set COMName=PC
예)
컴퓨터 아이피 끝 자리가 한 자리 숫자 192.168.0.5 라면 컴퓨터 이름은 PC005로 설정됩니다.
컴퓨터 아이피 끝 자리가 두 자리 숫자 192.168.0.11 라면 컴퓨터 이름은 PC011로 설정됩니다.
컴퓨터 아이피 끝 자리가 세 자리 숫자 192.168.0.121 라면 컴퓨터 이름은 PC121로 설정됩니다.
본인 기호에 맞게 컴퓨터 이름 'PC'를 수정하시면 되겠습니다.
[실행방법]
1. 채굴기용 원본 하드디스크를 세팅하시고, 바탕화면에 본 배치파일 IpComNameSet.cmd 를 복사해 둡니다.
2. PC 조립 후 첫 부팅 후에 바탕화면에 있는 IpComNameSet.cmd 를 실행(관리자권한)하면 아래와 같이 아이피 번호 뒷자리를 입력합니다.
3. 끝났습니다. 아이피는 192.168.0.25로 설정되었고, 컴퓨터 이름은 PC025로 적용되었습니다.
구성된 DNS 서버가 올바르지 않거나 존재하지 않습니다. 라는 메시지는 무시하셔도 됩니다. 확인해 보시면 적용된 것을 알 수 있습니다.
*첨부한 IpComNameSet.png 파일 다운로드 하셔서 확장명은 cmd로 변경하시면 됩니다.
도움 되시기 바라겠습니다.
====================배치파일 소스입니다. IpComNameSet.cmd로 저장하세요. =========================
@echo off
set NIC=이더넷
set GATEWAY=192.168.0.1
set SUBNET=255.255.255.0
set DNS1=168.126.63.1
set DNS2=168.126.63.2
cls
echo.
set /p IPend=설정하려는 아이피 뒷자리 입력 :
echo Subnet Mask : %SUBNET%
for /f "tokens=1-4 delims=." %%a in ('echo %GATEWAY%') do set IP=%%a.%%b.%%c.%IPend%
echo Gateway : %GATEWAY%
echo DNS Server 1 : %DNS1%
echo DNS Server 2 : %DNS2%
echo.
netsh interface ip set address %NIC% static %IP% %SUBNET% %GATEWAY%
netsh interface ip set dnsservers %NIC% static %DNS1% primary
netsh interface ip add dnsservers %NIC% INDEX=2 %DNS2%
if %IPend% LSS 10 set COMName=PC00
if %IPend% GTR 9 set COMName=PC0
if %IPend% GTR 99 set COMName=PC
ECHO y|REG add HKLM\SYSTEM\CurrentControlSet\Services\Tcpip\Parameters /v Hostname /t REG_SZ /d %COMName%%IPend% > nul
ECHO y|REG add HKLM\SYSTEM\CurrentControlSet\Services\Tcpip\Parameters /v "NV Hostname" /t REG_SZ /d %COMName%%IPend% > nul
ECHO y|REG add HKLM\SYSTEM\CurrentControlSet\Control\ComputerName\ComputerName /v ComputerName /t REG_SZ /d %COMName%%IPend% > nul
echo 컴퓨터 이름이 %COMName%%IPend% 으로 변경되었습니다.
::del C:\Users\ifcrypto\Desktop\IpSet.lnk
echo 작업이 완료되었습니다. 창을 닫아주세요.
pause > nul
shutdown -r -t 0
exit
======================================================================
-------------------------------------
꼬리말
* 게시글 내용 삭제시 레벨 강등
* 질문은 각 주제별 게시판에.
비트코인 암호화화폐 커뮤니티 땡글~ 땡글~
-------------------------------------