https://www.ddengle.com/miningbitcoin/2911474
한가지 수정된 부분이 있어서 링크 새로 달아둡니다.
위의 링크 첨부파일 받아주세요.
기본적인 셋팅은 지금 보고 계신 글의 내용을 봐주시면 됩니다.
위의 링크에 첨부된 배치파일 살펴보시면 라인별로
설명은 거의 다 달려있으니 참고하시길 바랍니다.
===========================================================
앞서 배치파일 내용 한번 올리고 난뒤 추가로 바라는 내용들을
몇군데 수정해서 테스트 하고 올립니다.
참고삼아 돌리는 채굴기 그래픽 카드는 Nvidia입니다.
amd도 아마 별다른 차이는 없을건데 특정 코인에서 돌리는 프로그램이 다른게
있을건데 그건 여기 배치파일 수정해서 사용하시면 될것 같습니다.
amd카드가 없어서 확인을 제가 못해드립니다.
현재 듀얼로 돌아가는 배치파일이 아닙니다.
전부 싱글로 돌아가도록 셋팅된 배치파일 내용이니 듀얼로 바꾸실려면
배치파일을 수정을 해서 사용하셔야합니다.
본문에 포함된 2개의 배치파일을 첨부파일로 올렸습니다.
kill.png 파일과 start.png 파일 2개를 다운 받으신후 확장자만 bat로 바꾸신후
파일내의 프로그램 경로를 바꿔주시길 바랍니다.
잘몰라서 바꾸기 어려우신분은 클레이모어 프로그램 폴더를 이름을 Miner_v9.8로 변경하신후
c:\로 복사해주세요. c:\Miner_v9.8 이 폴더안에 기존의 크레이모어 프로그램이 들어있으면 됩니다.
그리고 ewbf프로그램 폴더와 ccminer 폴더를 c:\Miner_v9.8 폴더안으로 복사를 해주세요
물론 ewbf 폴더명 ccminer 폴더명으로 해서 복사해주셔야합니다.
하단의 사진처럼 해주시면 됩니다.
물론 배치파일 다루실수있는 분이라면 변경해서 사용하시면 됩니다.
댓글로 물어보시는 분들이 있으셔서.. 연락처 알려드리니.. 아무도 전화를 안하시네요 ^^
그리고 kill.bat 와 start.bat 파일은 Miner_v9.8 폴더안에 넣어주시면 됩니다.
그리고 다른건 몰라도 start.bat 파일의 4번째 줄
SET a=풀ID.워커 <--- 이부분에서 풀ID와 워커는 필히 입력하셔야합니다.
현재 채굴기에서는 수정된 내용으로 해서 돌아가는 중입니다.
아래 사진이 기본 화면입니다.
아래 화면이 코인을 선택후 실행할때 화면입니다.
코인을 선택후 실행을 하면 현재 돌고 있는 채굴 프로세서 3개를 중지시켜버리고 선택한 코인을 채굴합니다
처음 실행시는 당연히 중지시킬 프로세서가 없으니 그냥 오류 3개가 뜰텐데 무시하시면 됩니다.
프로세스 중지 시키고 5초 이후 채굴 프로그램 동작하도록 해놨습니다.
바로 실행하면 아무래도 컴퓨터 무리가 갈수 있어서 최소 5초의 여유는 주고 프로그램 동작합니다.
아래 화면은 임의로 제크캐시 채굴을 선택한뒤 화면입니다.
채굴 화면뒤에 메뉴화면 도스창 보이시죠
저상태에서 이더를 캐실려면 메뉴화면 도스창 선택해서 1번 이더 엔터 치시면
채굴 프로그램 자동중지되고 5초 이후 이더리움 채굴창 뜰겁니다. 이제 배치파일 내용 올릴께요
배치파일은 2개입니다.
한개는 채굴용 프로세서 3개를 강제종료 시키는 파일입니다.
배치파일 내용상 강제종료 시키는 파일명은 kill.bat 로 초기 설정되어있습니다.
kill.bat 내용
========================================
taskkill /IM EthDcrMiner64.exe /t /f
taskkill /IM miner.exe /t /f
taskkill /IM ccminer-x64.exe /t /f
ECHO 5초 이후 채굴 프로그램이 실행합니다 기다려주세요
timeout /t 5
========================================
간단하게 배치파일 내에서 지원하는 채굴 프로그램은 3가지입니다.
크레이모어 , ccminer , ewbf 이렇게 3종류입니다. 크레이모어는.. 영어가 길어서.. 치기 귀찮아요 ㅠㅠ
나머지 다른 부분들은 배치파일 내용안에 주석을 달아둔 상태여서 그거 보시면 될것같습니다.
이제까지 계속 도움만 받다가 저도 받은 만큼 작게나마 도움이 되고자 올립니다.
kill.bat 나 start.bat 파일 위치에 따라서 경로도 다 변경해주셔야합니다.
하단 배치파일 위치에 맞추실려면
크레이모어는 c:\Miner_v9.8 폴더
ccminer는 c:\Miner_v9.8\ccminer 폴더
ewbf는 c:\Miner_v9.8\ewbf 폴더입니다.
kill.bat 파일은 c:\Miner_v9.8 폴더에 같이 들어있는걸로 됩니다.
다른 폴더 변경시 하단 start.bat 파일 내의 경로 위치 변경해주세요
아 그리고 8번 LBRY코인은 마이닝풀허브가 아닌 슈퍼노바 풀의 주소입니다.
LBRY코인은 마이닝풀허브에서 지원을 하지 않아서 슈퍼노바로 체인지해서 올린겁니다
나머지 다른 코인들은 마이닝풀허브의 주소입니다.
그리고 기타 각 코인별로 들어가는 개별 옵션은 배치파일 조정을 각각 하셔야합니다
그럼 도움이 되길 바라며 이만 마치고 start.bat에 해당하는 내용 올라갑니다.
========================================
@ECHO OFF
:MENU
REM a= 풀ID.워커명 입력란입니다. ID와 워커명 사이 . 빠뜨리지마시길 바랍니다.
SET a=풀ID.워커
REM 이 라인부터 밑으로 === 라인 사이에 있는 8개 줄은
REM 사용자 여러분의 실행파일 및 배치파일 경로는 지정해주는
REM 구간입니다. 정확하게 경로 변경을 해주시길 바랍니다.
REM================================================================================
REM Claymore dual miner 실행파일 위치 지정 라인 입니다.
SET clay=cmd.exe /c start /realtime c:\Miner_v9.8\EthDcrMiner64.exe
REM Ccminer 실행 파일 위치 지정 변수 입니다.
SET ccminer=cmd.exe /c start /realtime c:\Miner_v9.8\ccminer\ccminer-x64.exe
REM Ewbf 실행 파일 위치 지정 변수입니다.
SET ewbf=cmd.exe /c start /realtime c:\Miner_v9.8\EWBF\miner.exe
REM 프로세서 킬 배치 파일 위치 지정 변수입니다.
SET k=Call c:\Miner_v9.8\kill.bat
REM================================================================================
CLS
REM 메뉴 화면입니다.
ECHO ===========================
ECHO 1.이더리움 채굴
ECHO 2.이더리움 클래식 채굴
ECHO 3.뮤직코인 채굴
ECHO 4.Z-Cash 채굴
ECHO 5.Virt-Coin 채굴
ECHO 6.Z-Classic 채굴
ECHO 7.모네로 채굴
ECHO 8.LBRY-Coin 채굴
ECHO 9.프로그램 종료
ECHO ===========================
REM 8종류의 코인 채굴 선택 모드입니다.
REM 해당 코인 숫자키 누르시면 자동 실행합니다.
REM 기존 60초 후 특정 코인 자동 실행 옵션은 삭제합니다.
REM 처음 올린 배치파일은 채굴 코인을 선택한뒤
REM 다른 코인을 캘때 동작중인 채굴 프로그램을 종료를 한뒤
REM 배치파일을 다시 실행시키는 형태였습니다.
REM 지금 올리는 배치파일은 특정 코인 선택한뒤에 메뉴화면창은
REM 그대로 남아있습니다. 그창에서 다른 코인 선택하면
REM 자동으로 현재 채굴 프로그램 강제종료 시키면서
REM 5초뒤 새로 선택한 코인 채굴이 시작될것입니다.
CHOICE /C:123456789 /N /M "YOUR CHOICE? (원하는 코인 눌러주세요. 저 놀까요?) "
REM 9번 선택시 프로그램 종료합니다.
IF ERRORLEVEL 9 GOTO END
REM 8번 선택시 LBRY-코인 채굴 프로그램 실행 그룹으로 이동합니다.
IF ERRORLEVEL 8 GOTO 8
REM 7번 선택시 모네로-코인 채굴 프로그램 실행 그룹으로 이동합니다.
IF ERRORLEVEL 7 GOTO 7
REM 6번 선택시 Z-Classic 채굴 프로그램 실행 그룹으로 이동합니다.
IF ERRORLEVEL 6 GOTO 6
REM 5번 선택시 Virt-Coin 채굴 프로그램 실행 그룹으로 이동합니다.
IF ERRORLEVEL 5 GOTO 5
REM 4번 선택시 Z-Cash 채굴 프로그램 실행 그룹으로 이동합니다.
IF ERRORLEVEL 4 GOTO 4
REM 3번 선택시 뮤직 코인 실행 그룹으로 이동합니다.
IF ERRORLEVEL 3 GOTO 3
REM 2번 선택시 이더리움 클래식 채굴 프로그램 실행 그룹으로 이동합니다.
IF ERRORLEVEL 2 GOTO 2
REM 1번 선택시 이더리움 채굴 프로그램 실행 그룹으로 이동합니다.
IF ERRORLEVEL 1 GOTO 1
GOTO MENU
REM ================================================================
REM 이더리움 채굴 파일 실행창입니다. 1번 선택시 이동
REM 배치파일 제일 위에 실행 파일의 디렉토리와 실행 파일 이름을
REM 변경해 주셨다면 그대로 진행하시면 됩니다.
REM %k%는 기존 채굴 프로세서 킬 시키는 변수 명령어입니다.
REM timeout /t 5는 프로세서 킬을 한 다음 5초 대기이후 채굴시작
:1
%k%
%clay% -epool asia1.ethereum.miningpoolhub.com:20535 -ewal %a% -eworker %a% -esm 2 -epsw x -allpools 1 -allcoins 1 -dbg -1 -dcri 5 -ethi 8 -r 1 -ftime 30
GOTO MENU
REM ================================================================
REM 이더리움 클래식 채굴 파일 실행 그룹입니다. 2번 선택시 이동
:2
%k%
%clay% -epool asia1.ethereum.miningpoolhub.com:20555 -ewal %a% -eworker %a% -esm 2 -epsw x -allpools 1 -allcoins 1 -dbg -1 -dcri 5 -ethi 8 -r 1 -ftime 30
GOTO MENU
REM ================================================================
REM 뮤직코인 채굴 파일 실행 그룹입니다. 3번 선택시 이동
:3
%k%
%clay% -epool asia.ethash-hub.miningpoolhub.com:20585 -ewal %a% -eworker %a% -esm 2 -epsw x -allpools 1 -allcoins 1 -dbg -1 -dcri 5 -ethi 8 -r 1 -ftime 30
GOTO MENU
REM ================================================================
REM Z-cash코인 채굴 파일 실행 그룹입니다. 4번 선택시 이동
:4
%k%
%ewbf% --server asia.equihash-hub.miningpoolhub.com --user %a% --pass x --fee 0 --port 20570 --api 0.0.0.0:42000
GOTO MENU
REM ================================================================
REM Virt코인 채굴 파일 실행 그룹입니다. 5번 선택시 이동
:5
%k%
%ccminer% -a lyra2v2 -o stratum+tcp://hub.miningpoolhub.com:20507 -u %a% -p x --api-bind 0.0.0.0:4068
GOTO MENU
REM ================================================================
REM Z-Classic코인 채굴 파일 실행 그룹입니다. 6번 선택시 이동
:6
%k%
%ewbf% --server asia.equihash-hub.miningpoolhub.com --user %a% --pass x --fee 0 --port 20575 --api 0.0.0.0:42000
GOTO MENU
REM ================================================================
REM Monero코인 채굴 파일 실행 그룹입니다. 7번 선택시 이동
:7
%k%
%ccminer% -a cryptonight -o stratum+tcp://asia.cryptonight-hub.miningpoolhub.com:20580 -u %a% -p x --api-bind 0.0.0.0:4068
GOTO MENU
REM ================================================================
REM LBRY코인 채굴 파일 실행 그룹입니다. 8번 선택시 이동
:8
%k%
%ccminer% -o stratum+tcp://lbry.suprnova.cc:6256 -u %a% -a lbry --api-bind 0.0.0.0:4068
GOTO MENU
REM ================================================================
REM 프로그램 종료 그룹입니다. 9번 선택시 이동하는 그룹
:END
EXIT